Simple syntax for a list with "or"?

[aschultz]

Most of the time, ‘[the list of dishes]’ works great.

But I ran into a case where I definitely need ‘or’ instead of ‘and.’

The “dish-list” code below works, but is there a one-liner available to simplify things?

"Stuff" by Andrew Schultz

a dish is a kind of thing.

r1 is a room

the chicken is a dish in r1.
the veal is a dish in r1.
the fish is a dish in r1.

every turn:
	say "Which dish will you pick, [dish-list]?";

to say dish-list:
	let Z be the number of dishes;
	let count be 0;
	repeat with X running through dishes:
		increment count;
		say "[the x]";
		if count < z, say ", ";
		if count is z - 1, say "or ";

(Note: I had trouble following the I6 code down to WriteListR, but that could be an alternate solution, to add a flag for OR or AND. But that’d be a bit beyond me.)

[Zed (Zed Lopez)]

Narrator’s voice: Two years earlier…

Putting "or" in a list instead of "and"

I have text saying, for instance, “you can move your king to b8, c8, c7 and c6.” But it would technically be more grammatically accurate to say “you can move your king to b8, c8, c7 or c6.” So I have this code comparing the shorthand “list of adjacent rooms” with something longer. But what I’m wondering is, is there shorthand Inform 7 that says “[list of adjacent rooms with conjunction = or]”? every turn: say "[list of adjacent rooms]."; let x be number of adjacent rooms; let count be 0; r…

Lab is a room.

To say or-list (l - list of values):
  now or-not-and is true;
  say l;
  now or-not-and is false.

or-not-and is initially false.

L is initially {1 , 2, 3};

For issuing the response text of the list writer internal rule response (C) when or-not-and is true: say " or ".

when play begins:
  say "[or-list L]".

Edited: Actually, this is less ugly:

list-conjunction is initially "and".

To say (l - list of values) with conjunction (t - text):
  let backup be list-conjunction;
  now list-conjunction is t;
  say l;
  now list-conjunction is backup.

To say or-list (l - list of values):
  say l with conjunction "or";

For issuing the response text of the list writer internal rule response (C): say " [list-conjunction] ".

[aschultz]

Oops! Well, thanks for the quick reply. I’m bookmarking it/writing it in my big notes file this time!

I usually keep a repository of “weird stuff I will likely use again” but somehow this slipped through. Fingers crossed it won’t happen a third time.

[BadParser]

@Zed

To say (l - list of values) with conjunction (t - text):
  let backup be list-conjunction;
  now list-conjunction is "or";
  say l;
  now list-conjunction is backup.

To say or-list (l - list of values):
  say l with conjunction "or";

Shouldn’t that first block read:

To say (l - list of values) with conjunction (t - text):
  let backup be list-conjunction;
  now list-conjunction is t;
  say l;
  now list-conjunction is backup.

[Zed (Zed Lopez)]

@BadParser

Shouldn’t that first block read:

Yup! I’ve edited the post now.