This is a simple game done in ScottKit as a basic prototype for my Text Adventure Construction Kit (TACK). Comments welcome. I’m especially looking for commands that is relevant to modern IF gaming.
About 2 hours design on paper and 1.5 hours ScottKit coding and testing.
start rockypath
treasury victory
room limbo "Limbo"
room rockypath "Rocky Path"
exit north grassyplain
item rock "rock" called "rock"
room grassyplain "Grassy Plain"
exit north sandybeach
exit west cactuspatch
exit south rockypath
exit east grassyhill
room cactuspatch "Cactus Patch"
exit east grassyplain
item lion "Lion" called "lion"
occur
select_counter 2
occur when counter_le 1
set_counter 2
occur 25%
dec_counter
occur when counter_eq 2 and exists lion
put lion grassyplain
occur when counter_eq 1 and exists lion
put lion cactuspatch
occur 50% when counter_eq 2 and exists lion and here lion
print "The lion roars across the plain."
occur 50% when counter_eq 2 and exists lion and at rockypath
print "You hear a lion roars"
occur 70% when here lion
print "The lion stares at you."
occur 10% when here lion
print "The lion eats you!"
game_over
print "Throw rock to scare the lion."
action throw rock when carried rock and here lion
print "The lion runs away!"
destroy lion
drop rock
action get lion when here lion
print "The lion eats you!"
game_over
print "Throw rock to scare the lion."
action cut lion when here lion
print "The lion eats you!"
game_over
print "Throw rock to scare the lion."
action throw lion when here lion
print "The lion eats you!"
game_over
print "Throw rock to scare the lion."
room grassyhill "Grassy Hill"
exit west grassyplain
item grass "Clump of grass" called "grass"
action get grass
when present grass and !flag 2
print "You need to cut the grass first"
action cut grass
when present grass and carried rock and !flag 2
print "You cut the grass"
set_flag 2
action cut grass
when present grass and !flag 2
print "You need a sharp rock"
action cut grass
when present grass and flag 2
print "You already cut the grass"
room sandybeach "Sandy Beach"
exit north nearsidepond
exit south grassyplain
room nearsidepond "Nearside Pond"
exit north middlepond
exit south sandybeach
occur
when at nearsidepond and !carried grass
print "You sink to the bottom of the pond."
goto underwater
room underwater "Underwater"
exit south sandybeach
room middlepond "Middle of Pond"
exit north farendpond
exit south nearsidepond
room farendpond "Far End Pond"
item goose "*Golden Goose*" called "goose"
action throw rock when carried rock and here goose
print "The goose is annoyed at you."
put rock underwater
action cut goose when here goose
print "Don't kill the goose!"
game_over
print "You did the very opposite of what you're supposed to do!"
action throw goose when here goose
print "Let's not annoy the goose."
occur 25% when here goose
print "The goose honks happily."
occur 75% when here goose
print "The goose swims peacefully."
occur
when carried goose
print "You get the golden goose!"
print "Type SCORE to win the game."
goto victory
drop goose
room victory "Victory Room"
occur when at nearsidepond and !carried grass
goto underwater
occur when at middlepond and !carried grass
goto underwater
occur when at farendpond and !carried grass
goto underwater
action throw rock when at nearsidepond and carried rock
put rock underwater
action throw rock when at middlepond and carried rock
put rock underwater
action throw rock when at farendpond and carried rock
put rock underwater
action throw rock when carried rock
drop rock
action score: score
action inventory: inventory
action look: look
action save game: save_game
action quit game
print "Good bye!"
game_over
action quit:
print "type QUIT GAME to quit."
action cut:
print "You can't cut that."
action wear:
print "You can't wear that."
action throw:
print "You can't throw that."
verbgroup look Examine x
verbgroup get take g
verbgroup drop leave
verbgroup cut slice trim
verbgroup wear don
verbgroup throw lop cast swing
