Does [first time][only] not work anymore?

Authoring Inform 7
1

Sorry if I’m way behind, but I’m using 6L02 and [first time] [only] doesn’t seem to work anymore, even though it’s still listed in the documentation. This:

[code]The woods is a room.

The player is wearing a hat. The description of the hat is “A nice warm hat[first time]. You’ll appreciate it when winter comes[only].”

Test me with “x hat/x hat”.[/code]

Just says “A nice warm hat.” twice.

Meanwhile, the [one of] [stopping] syntax still works as desired:

[code]The woods is a room.

The player is wearing a hat. The description of the hat is “A nice warm hat[one of]. You’ll appreciate it when winter comes[or][stopping].”

Test me with “x hat/x hat”.[/code]

This prints “A nice warm hat. You’ll appreciate it when winter comes.” and then “A nice warm hat.”

Am I doing something wrong, or is [first time] [only] no longer supported?

2

There was a glitch where it temporarily went out, and people were substituting “[one of]This gets said once.[or][stopping]”

It works in the version I have…have you updated recently?

3

If you don’t want to upgrade to 6L38, you can also include this in your code to patch it for the time being.

Section - First Time Only (in place of Section SR5/1/4 - Saying - Say one of in Standard Rules by Graham Nelson)

[This fixes Bug 1291 for the time being.]

To say one of -- beginning say_one_of (documented at phs_oneof):
	(- {-counter-makes-array:say_one_of} if (say__comp == false) I7_ST_say_one_of-->{-counter:say_one_of} =
	{-final-segment-marker}(I7_ST_say_one_of-->{-counter:say_one_of}, {-segment-count});
	switch((I7_ST_say_one_of-->{-counter:say_one_of}{-counter-up:say_one_of})%({-segment-count}+1)-1) {-open-brace}
		0: -).
To say or -- continuing say_one_of (documented at phs_or):
	(- @nop; {-segment-count}: -).
To say at random -- ending say_one_of with marker I7_SOO_RAN (documented at phs_random):
	(- {-close-brace} -).
To say purely at random -- ending say_one_of with marker I7_SOO_PAR (documented at phs_purelyrandom):
	(- {-close-brace} -).
To say then at random -- ending say_one_of with marker I7_SOO_TRAN (documented at phs_thenrandom):
	(- {-close-brace} -).
To say then purely at random -- ending say_one_of with marker I7_SOO_TPAR (documented at phs_thenpurelyrandom):
	(- {-close-brace} -).
To say sticky random -- ending say_one_of with marker I7_SOO_STI (documented at phs_sticky):
	(- {-close-brace} -).
To say as decreasingly likely outcomes -- ending say_one_of with marker I7_SOO_TAP (documented at phs_decreasing):
	(- {-close-brace} -).
To say in random order -- ending say_one_of with marker I7_SOO_SHU (documented at phs_order):
	(- {-close-brace} -).
To say cycling -- ending say_one_of with marker I7_SOO_CYC (documented at phs_cycling):
	(- {-close-brace} -).
To say stopping -- ending say_one_of with marker I7_SOO_STOP (documented at phs_stopping):
	(- {-close-brace} -).

To say first time -- beginning say_first_time (documented at phs_firsttime): [This part has changed: I added the second if statement.]
	(-{-counter-makes-array:say_first_time}
	if (say__comp == false){-open-brace}if ((I7_ST_say_first_time-->{-counter:say_first_time}{-counter-up:say_first_time})++ == 0) {-open-brace}
		-).
To say only -- ending say_first_time (documented at phs_firsttime):
	(- {-close-brace}{-close-brace} -).
4

Just updated to 6L38 and it works now. Thanks!