diff --git a/misc.zil b/misc.zil
index 35506d6..87ab92a 100644
--- a/misc.zil
+++ b/misc.zil
@@ -4,6 +4,7 @@ Copyright (c) 1986 Infocom, Inc.  All rights reserved."
 <ROUTINE GO ()
 	;<SETG WINNER ,PLAYER>
 	;<START-MOVEMENT>
+	<INIT-STATUS-LINE>
 	<V-VERSION>
 	<INTRO>
 	<MAIN-LOOP>
@@ -203,8 +204,6 @@ I-WITHDRAW"
 
 "SCORE INDICATES HOURS / MOVES = MINUTES"
 
-<GLOBAL SCORE:NUMBER 19>
-<GLOBAL MOVES:NUMBER 0>
 <GLOBAL PRESENT-TIME:NUMBER <SETG PRESENT-TIME-ATOM 420 ;1140>>
 <GLOBAL CLOCKER-RUNNING:NUMBER 0>
 
@@ -273,10 +272,6 @@ I-WITHDRAW"
 	 <SETG PRESENT-TIME <+ ,PRESENT-TIME 1>>
 	 <COND (<G? ,PRESENT-TIME 1139 ;1859>
 		<TIMES-UP>)>
-	 <COND (<G? <SETG MOVES <+ ,MOVES 1>> 59>
-		<SETG MOVES 0>
-		<COND (<G? <SETG SCORE <+ ,SCORE 1>> 23>
-		       <SETG SCORE 0>)>)>
 	 <SET C <REST ,C-TABLE ,C-INTS>>
 	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
 	 <REPEAT ()
diff --git a/moonmist.zil b/moonmist.zil
index 49acb6c..fbb33d5 100644
--- a/moonmist.zil
+++ b/moonmist.zil
@@ -1,7 +1,16 @@
 "COMPILE/LOAD FILE for MOONMIST
 Copyright (C) 1986 Infocom, Inc.  All rights reserved."
 
-<CONSTANT RELEASEID 1> <VERSION ZIP TIME>
+;"EZIP is used rather than XZIP to avoid changes to the parse buffer."
+<CONSTANT RELEASEID 1> <VERSION EZIP>
+
+<CONSTANT NEW-VOC? T>
+
+;"Generate numbers for adjectives, since this is a V3 game at heart"
+<CONSTANT FORCE-V3-PARSER? T>
+
+;"Tell the game we're compiling for V4"
+<CONSTANT PLUS-MODE T>
 
 <FREQUENT-WORDS?>
 
@@ -16,6 +25,7 @@ Copyright (C) 1986 Infocom, Inc.  All rights reserved."
 <INSERT-FILE "macros">
 <INSERT-FILE "misc">
 <INSERT-FILE "parser">
+<INSERT-FILE "status">
 
 <INSERT-FILE "syntax">
 <INSERT-FILE "verbs">
diff --git a/parser.zil b/parser.zil
index d406c37..1e93c50 100644
--- a/parser.zil
+++ b/parser.zil
@@ -1203,7 +1203,7 @@ Now you can try again">)
 		      <CRLF>)>
 	       %<COND (<AND <GASSIGNED? PLUS-MODE> ,PLUS-MODE>
 		       '<PROG ()
-			      <USL>
+			      <UPDATE-STATUS-LINE>
 			      <TELL !\>>>)
 		      (T
 		       '<TELL !\>>)>
diff --git a/status.zil b/status.zil
new file mode 100644
index 0000000..8adc90d
--- /dev/null
+++ b/status.zil
@@ -0,0 +1,83 @@
+" Adapted from other XZIP games"
+<CONSTANT S-TEXT 0>
+<CONSTANT S-WINDOW 1>
+
+<CONSTANT H-NORMAL 0>
+<CONSTANT H-INVERSE 1>
+<CONSTANT H-BOLD 2>
+<CONSTANT H-ITALIC 4>
+
+<CONSTANT D-SCREEN-ON 1>
+<CONSTANT D-SCREEN-OFF -1>
+<CONSTANT D-PRINTER-ON 2>
+<CONSTANT D-PRINTER-OFF -2>
+<CONSTANT D-TABLE-ON 3>
+<CONSTANT D-TABLE-OFF -3>
+<CONSTANT D-RECORD-ON 4>
+<CONSTANT D-RECORD-OFF -4>
+
+<CONSTANT SL-TIME-LABEL-LOC 51>
+<CONSTANT SL-TIME-LOC 57>
+<CONSTANT SL-TIME-TOO-NARROW 62>
+
+<CONSTANT SL-TABLE:TABLE <ITABLE NONE 80>>  "status line constructed here"
+
+<GLOBAL OHERE-STATUS:OBJECT <>>
+<GLOBAL OLD-LEN:NUMBER 0>
+<GLOBAL WIDTH:NUMBER 0>
+
+<ROUTINE INIT-STATUS-LINE ()
+         <SETG WIDTH <LOWCORE SCRH>>
+         <CLEAR -1>
+         <COND (<L? ,WIDTH 38>
+                <TELL "[Screen too narrow.]" CR>
+                <QUIT>)>
+         <SETG OHERE-STATUS <>>
+         <SETG OLD-LEN 0>
+         <SPLIT 1>
+         <SCREEN ,S-WINDOW>
+         <HLIGHT ,H-INVERSE>
+         <CURSET 1 1>
+         <PRINT-SPACES ,WIDTH>
+         <COND (<G? ,WIDTH SL-TIME-TOO-NARROW>
+               <CURSET 1 ,SL-TIME-LABEL-LOC>
+               <TELL "Time:">)>
+         <HLIGHT ,H-NORMAL>
+         <SCREEN ,S-TEXT>
+         <RTRUE>>
+
+<ROUTINE UPDATE-STATUS-LINE ("AUX" HH)
+         <SCREEN, S-WINDOW>
+         <HLIGHT ,H-NORMAL>
+         <HLIGHT ,H-INVERSE>
+         <COND (<NOT <EQUAL? ,HERE ,OHERE-STATUS>>
+                <SETG OHERE-STATUS ,HERE>
+                <DIROUT ,D-TABLE-ON ,SL-TABLE>  ; "Print to table"
+                <SAY-HERE>
+                <DIROUT ,D-TABLE-OFF>
+                <CURSET 1 2>
+                <PRINT-SPACES ,OLD-LEN>  ; "Erase old HERE desc"
+                <SETG OLD-LEN <GET ,SL-TABLE 0>>
+                <CURSET 1 2>
+                <SAY-HERE>)>
+         <COND (<G? ,WIDTH SL-TIME-TOO-NARROW>
+                <CURSET 1 ,SL-TIME-LOC>
+                <TIME-PRINT ,PRESENT-TIME>
+                <PRINTC 32> ;"In case time gets smaller, e.g. 12:00->1:00")>
+         <HLIGHT ,H-NORMAL>
+         <SCREEN ,S-TEXT>
+         <RTRUE>>
+
+;"Much simpler than V5 SAY-HERE"
+<ROUTINE SAY-HERE ()
+         <PRINTC 32>
+         <PRINTD ,HERE>>
+
+<ROUTINE PRINT-SPACES (N)
+         <REPEAT ()
+                 <COND (<L? <SET N <- .N 1>> 0>
+                        <RTRUE>)>
+                 <PRINTC 32>>>
+                      
+<CONSTANT BLANKS-LEN 10>
+<CONSTANT BLANKS <ITABLE ,BLANKS-LEN (BYTE) !\ >>
diff --git a/verbs.zil b/verbs.zil
index bee84c2..abce8b4 100644
--- a/verbs.zil
+++ b/verbs.zil
@@ -3933,11 +3933,11 @@ CHE ,PRSO is !\  <GET ,LDESC-STRINGS 12> ;"listening to you" "." CR>)>)
 				      <SET VAL <TIME-PRINT ,PRESENT-TIME>>
 				      <TELL ") ">)>
 			       <COND (<T? ,KEEP-WAITING>
-				      <USL>
+				      <UPDATE-STATUS-LINE>
 				      <AGAIN>)>
 			       <TELL "Do you want to keep ">
 			       <SET VAL <VERB-PRINT T>>
-			       <COND (<YES?> <USL>)
+			       <COND (<YES?> <UPDATE-STATUS-LINE>)
 				     (T
 				      <SETG CLOCK-WAIT T>
 				      <SET RESULT ,M-FATAL>
@@ -3948,8 +3948,8 @@ CHE ,PRSO is !\  <GET ,LDESC-STRINGS 12> ;"listening to you" "." CR>)>)
 " still hasn't arrived. Do you want to keep waiting?">
 			<COND (<NOT <YES?>> <RETURN>)>
 			<SET WHO-WAIT 0>
-			<USL>)
-		       (T <USL>)>>
+			<UPDATE-STATUS-LINE>)
+		       (T <UPDATE-STATUS-LINE>)>>
 	 %<DEBUG-CODE <COND (<NOT .INT>
 			     <TELL "{" ;"Note to Stu: ">
 			     <TIME-PRINT ,PRESENT-TIME>