"Halloween Dance" by MathBrush

Section 1-Preliminaries

Release along with an interpreter and source text.

Abouting is an action out of world.

Understand "about" as abouting. Understand "help" as abouting. 

Carry out abouting:
	say "Halloween Dance is a SpeedIF for Ectocomp. It was completed in 3 hours. I wrote it to try a new conversation system. The game has 3-5 endings (two of them have small variations).
	
	Topics are in your inventory. You can TELL them to someone, SAY them to someone, or GIVE them to someone. Topics can appear or disappear.
	
	This game has several endings, some requiring more work than the others.
	
	To hear my thoughts about the new system, type 'SYSTEM'.
	
	Felicity Banks and Andrew Schultz gave it a quick run-through to make sure it worked.";

Systeming is an action out of world. Understand "system" as systeming.

Carry out systeming:
	say "Many people have complained over the years about the ask/tell conversation system and the menu system, so I wanted to try something a little different.
	
	My idea is to make conversation more like the parser world. The options available to you in a parser game are very limited compared to your options in real life; what makes it fun is that you gather items and push things and so on, wandering around a map, and you never know when you will use different items. And you can use each item on everything you see.
	
	So my ideas I'm trying are:
	1.  a persistent inventory that you can try out with a variety of people,
	2.  the ability to collect and lose topics in connection with conversations and in-world actions
	3.  identifying topics with tags (similar to 'ask about dog'), but including a piece of what you will actually say along with the tag (similar to the menu-based systems)
	";

Dance Hall is a room. The description of Dance Hall is "A school gymnasium with four or five pumpkins on the side and orange and black streamers hanging from the ceiling.[first time][paragraph break][bracket]Conversation in this game is handled by typing 'SAY topic TO person'. Your topics are listed in your inventory, which you can reach by typing 'i'.[close bracket][only]"

The pumpkins are scenery. The description of pumpkins is "The pumpkins have ghosts carved into them.". Understand "pumpkin" as pumpkins.

After examining the pumpkins for the first time:
	now the player is carrying GhostQuip;
	say "[bracket]New topic: Ghosts[close bracket]"

The description of the player is "You're wearing a costume.";

The streamers are scenery. The description of the streamers is "The streamers are orange and black. A spider scurries across it and out of sight."

Understand "topics" or "t" as taking inventory.

The pumpkins and streamers are in Dance Hall.

A quip is a kind of thing. A riposte is a kind of quip. A query is a kind of thing.

A namequip is a kind of quip.

Instead of dropping a quip:
	say "You can't drop that."

Understand "tell [something] to [someone]" as giving it to.

Understand "say [something] to [someone]" as giving it to.

Section 2-Characters

A person has a number called NameTold. NameTold is usually 0. A person has a number called CostumeLiked. CostumeLiked is usually 0.

Fred is a man. Jane is a woman. Fred is in Dance Hall. Jane is in Dance Hall.  

Dancing is an action applying to nothing.

Understand "dance" as dancing.

Instead of dancing:
	say "You [one of]do the robot[or]break dance[or]do the macarena[or]bob your head[at random]."

The description of Fred is "A young man wearing a white suit with red splatters all over. He is standing next to a cooler with mist coming out of it."

The description of Jane is "A young woman wearing a simple frock covered with dozens of old... are those beepers? Like from the 90's?"

FredQuip is a namequip. The printed name of FredQuip is "About Fred-'So, what do you know about Fred?'".
Understand "About Fred" as FredQuip.

JaneQuip is a namequip. The printed name of JaneQuip is "About Jane-'So, what do you know about Jane?'".
Understand "About Jane" as JaneQuip.

The cooler is in the  Dance Hall. The description of the cooler is "A small blue cooler with mist coming out of it."

Instead of taking the cooler:
	say "That belongs to someone else."

Instead of opening the cooler:
	say "That's already open."

Instead of looking in the cooler:
	say "The boy says 'Hey, that's mine!'"

The brainpop is a thing. The description of brainpop is "A homemade popsicle with some kind of mush in it."

The costume is a thing. The description of costume is "A Phantom of the Schoolhouse costume, complete with gloves and mask." The printed name of costume is "Your costume (being worn)". Understand "my costume" as costume. Understand "your costume" as costume. Understand "glove" as costume. Understand "mask" as costume. Understand "gloves" as costume.

After examining the costume for the first time:
	now the player is carrying MyCostume;
	say "[bracket]New topic: Phantom[close bracket]"

Instead of taking off costume:
	say "You don't want to take that off now."

Instead of dropping costume:
	say "You actually aren't wearing anything underneath. Better hold on to it."

Instead of taking inventory:
	say "[bold type]Items:[roman type][line break]";
	repeat with current running through things carried by the player:
		if current is not a quip:
			say "    [current][line break]";
	say "[bold type]Topics:[roman type][line break]";
	repeat with current2 running through quips carried by the player:
		say "    [current2][line break]"

Section 3-Specific quips

MyName is a quip. The printed name of MyName is "Greeting-'Hi! My name is Gerald.'" Understand "greeting" as MyName.

CostumeCompliment is a quip. The printed name of CostumeCompliment is "Compliment-'Wow, nice costume!'". Understand "compliment" as CostumeCompliment.

NoThanks is a riposte. The printed name of NoThanks is "Uhh-'Actually, I'm not interested.'". Understand "Uhh" as NoThanks.

YeahSure is a riposte. The printed name of YeahSure is "Okay-'Why not?'". Understand "Okay" as YeahSure.

Before giving something (called the givee) to someone:
	if the givee is not a riposte:
		repeat with current running through ripostes carried by the player:
			now current is nowhere;
	
Instead of giving MyName to someone (called buddy):
	if NameTold of buddy is 1:
		say "'Hi! My name is Gerald.'[paragraph break]'Yeah, I know.'";
	otherwise:
		now NameTold of buddy is 1;
		say "'Hi! My name is Gerald.'[paragraph break]'Hi! my name is [buddy]!'";
		if buddy is Fred:
			now the player is carrying FredQuip;
			say "[first time][line break][bracket]New topic: About Fred[close bracket][only]";
		if buddy is Jane:
			now the player is carrying JaneQuip;
			say "[first time][line break][bracket]New topic: About Jane[close bracket][only]";

Instead of giving CostumeCompliment to someone (called buddy):
	say "'Wow, nice costume'";
	if CostumeLiked of buddy is 0:
		if buddy is Fred:
			say "!'[paragraph break]'Thanks! I'm a zombie ice cream man selling brainpops. You want one?'";
			now the player is carrying NoThanks;
			now the player is carrying YeahSure;
			say "[first time][line break][bracket]New topics: Okay and Uhh[close bracket][only]";
		if buddy is Jane:
			say "!'[paragraph break]'Awww, you're sweet! I'm the Grim Beeper, reminding all technology that it will one day be obsolete.'";
	otherwise:
		say "![paragraph break]'Thanks, but you told me that already.'";

Instead of giving YeahSure to Fred:
	say "'Why not?'[paragraph break] He hands you a brainpop.";
	now the player is carrying the brainpop;
	now NoThanks is nowhere;
	Now YeahSure is nowhere;

Instead of giving NoThanks to Fred:
	say "'Actually, I'm not interested.'[paragraph break]He shrugs.";
	now NoThanks is nowhere;
	Now YeahSure is nowhere;

Instead of eating the brainpop:
	say "Wow! That really hits the spot! The mush was strawberries.";
	now the brainpop is nowhere.
	
StrawQuip is a quip. The printed name of StrawQuip is "Strawberries-'Did you know [if the player is carrying JaneQuip]Jane[otherwise]that girl over there[end if] doesn't like strawberries?'". Understand "strawberries" as StrawQuip.

Strawgiven is a number that varies. Strawgiven is usually 0.

Instead of giving the brainpop to Jane:
	say "She grimaces and says, 'No thanks, I don't like strawberry.'";
	now the player is carrying StrawQuip;
	say "[first time][line break][bracket]New topic: Strawberries[close bracket][only]";

Instead of giving StrawQuip to Fred:
	say "'Did you know [if the player is carrying JaneQuip]Jane[otherwise]that girl over there[end if] doesn't like strawberries?'[line break][if Strawgiven is 0]Fred's face blanches. He says, 'Aw, crap,' and hangs his head.[otherwise]'Yeah, I know.'[end if]";
	now Strawgiven is 1;

Instead of giving JaneQuip to Fred:
	say "'So, what do you know about Jane?'[paragraph break]He looks at Jane, then leans forward and whispers, 'Can you keep a secret? Jane has been my crush for two years now. I heard she likes walking dead, so I made this whole getup and these brainpops to impress her[if Strawgiven is 1]. But apparently she hates strawberries...'[otherwise].'[end if]";
	now the player is carrying FredLikes;
	now the player is carrying LieQuip;
	say "[first time][line break][bracket]New topics: Crush and Lie[close bracket][only]";

Instead of giving JaneQuip to Jane:
	say "'So, what do you know about Jane?'[paragraph break]Jane gives you a dumb look and says, 'I AM Jane.'"

Instead of giving FredQuip to Jane:
	say "'So, what do you know about Fred?'[line break]She brightens up, peeking over at Fred. 'Can you keep a secret? I think Fred is the sweetest man at school. He's really into repairing old technology, so I made this costume for him.' She twirls to display her outfit. 'I love fixing old stuff too, That's how we met, in our Tech class.'";
	now the player is carrying JaneLikes;
	say "[first time][line break][bracket]New topic: Romance[close bracket][only]";

Instead of giving FredQuip to Fred:
	say "'So, what do you know about Fred?'[paragraph break]Fred gives you a dumb look and says, 'I AM Fred.'"

MyCostume is a quip. The printed name of MyCostume is "Phantom-'What do you think about my costume?'". Understand "Phantom" as MyCostume.

CostumeSaid is a number that varies. CostumeSaid is usually 0.

Instead of giving MyCostume to someone:
	now CostumeSaid is 1;
	say "'What do you think about my costume?'[paragraph break]'It's nice! What are you?'[paragraph break]'I'm the Phantom of the Schoolhouse.'[paragraph break]'Cool! I didn't think they let people wear masks anymore.' They hesitate for a moment. 'To be honest, I've been wondering if you even go to this school.'[paragraph break]";
	now MyCostume is nowhere;
	if GhostSaid is 1:
		say "'I don't' you say, as you carelessly remove your mask. Fred screams as Jane backs against the wall. Your transparent skin glows softly in the flourescent light. 'At least, not anymore.'[paragraph break]You grab the brainpops and float through the ceiling. You look at Jane one last time. 'Tell Fred thanks for the pops.'";
		end the story finally saying "You've kept the legend alive, and made off with the brainpops.";
	otherwise:
		say "'Let's just say that I already graduated. Don't tell anyone.'";
	
FredLikes is a quip. The printed name of FredLikes is "Crush-'So, I found out who Fred is interested in...'". Understand "Crush" as FredLikes.

JaneKnows is a number that varies. JaneKnows is usually 0.

FredKnows is a number that varies. FredKnows is usually 0.

Instead of giving FredLikes to Jane:
	say "'So, I found out who Fred is interested in...'[paragraph break]'Really?'[paragraph break]'He told me he's had a crush on you for two years'.";
	now JaneKnows is 1;
	if FredKnows is 1:
		say "[paragraph break]Jane turns to Fred and smiles. She walks over and draws him to the side. You see the two of them laughing together, and then Jane kisses Fred on the cheek and he blushes. Fred turns to you as they walk out together, and gives you a thumbs up.";
		end the story finally saying "You had some fun, and got the rest of the brainpops.";
	otherwise:
		say "Jane beams from ear to ear, and keeps glancing at Fred.";
	now FredLikes is nowhere;
	now LieQuip is nowhere;
		
JaneLikes is a quip. The printed name of JaneLikes is "Romance-'So, I found out who Jane is interested in...'" Understand "Romance" as JaneLikes.

Instead of giving JaneLikes to Fred:
	say "'So, I found out who Jane is interested in...[paragraph break]He looks upset for a second. 'Who?'[paragraph break]'She said she's been into you ever since Tech class. She wore the beeper dress just for you.";
	now FredKnows is 1;
	if JaneKnows is 1:
		say "[paragraph break]Fred looks over at Jane, leaving the brainpops behind. He turns behind, and says, 'Hey, take the rest of them. I don't need them anymore.'[paragraph break]He walks up to Jane and starts pointing at her costume. You hear them laughing together. As they talk, his hand brushes hers, and she smiles. You turn away and enjoy your reward.";
		end the story finally saying "You had some fun, and got the rest of the brainpops.";
	otherwise:
		say "Fred seems noticeably more cheerful.";
	now FredLikes is nowhere;

GhostQuip is a quip. The printed name of GhostQuip is "Ghosts-'Do you believe in ghosts?'". Understand "ghosts" as GhostQuip.

GhostSaid is a number that varies. GhostSaid is usually 0;

Instead of giving GhostQuip to someone:
	now GhostSaid is 1;
	say "'Do you believe in ghosts?'[paragraph break]'Not really, why?'[paragraph break]'They say that a kid died in this gym 40 years ago at a Halloween party'.[paragraph break]'How did he die?'[paragraph break]'His costume caught on fire on a tiki torch against the wall. He tried to take it off, but his zipper was stuck. He ran out into the night to try and reach a pond but he didn't make it";
	if CostumeSaid is 1:
		say ". Which is why', you say, taking off your mask, 'I always have to wear this now.'[paragraph break]Fred screams and faints in Jane's arm, while Jane panics. Laughing, you remove the rest of your costume, and float through the wall.";
		end the story finally saying "Your legend lives.";
	otherwise:
		say ".'[paragraph break]'You're creeping me out, man!'";
	now GhostQuip is nowhere;

LieQuip is a quip. The printed name of LieQuip is "Lie-'Fred told me he hates your guts.'". Understand "lie" as LieQuip.

Instead of giving LieQuip to Fred:
	say "I don't think that's a good idea."
	
Instead of giving LieQuip to Jane:
	say "'Fred told me hates your guts. He even put strawberry in those popsicles because he knows you hate it.'[paragraph break]Jane storms away, glaring at Fred. Fred looks at her, perplexed, then back at you. You ignore Fred, and look at the pumpkins instead. Oooh, nice ghost carving.";
	end the story finally saying "Noone is happy now.";

Section 4-Prologue

When play begins:
	now the player is carrying costume;
	now the player is carrying MyName;
	now the player is carrying CostumeCompliment;