"adjacency test" by david j prokopetz

section 1 - adjacency rules

Visual adjacency relates various rooms to each other.

The verb to be visually adjacent to implies the visual adjacency relation.

Aural adjacency relates various rooms to each other.

The verb to be aurally adjacent to implies the aural adjacency relation.

Asking is auralising.
Asking about is auralising.
Telling about is auralising.
Listening is auralising.

Asking is auralising-to.
Asking about is auralising-to.
Telling about is auralising-to.

Listening is auralising-from.

Examining is visualising.

After deciding the scope of the player:
	repeat with locale running through rooms which are visually adjacent to the location of the player:
		place locale in scope;

After deciding the scope of the player while auralising:
	repeat with locale running through rooms which are aurally adjacent to the location of the player:
		place locale in scope;		

the adjacency-aware can't reach inside rooms rule is listed instead of the can't reach inside rooms rule in the reaching inside rules.
this is the adjacency-aware can't reach inside rooms rule:
	if auralising:
		if the location of the noun is aurally adjacent to the location of the player:
			allow access;
		otherwise:
			if the location of the noun is visually adjacent to the location of the player:
				if auralising-from:
					say "You can see [the noun], but you can't hear a thing.";
					deny access;
				otherwise if auralising-to:
					say "[the noun] can't hear you.";
					deny access;
				otherwise:
					abide by the can't reach inside rooms rule;				
			otherwise:
				abide by the can't reach inside rooms rule;
	otherwise if visualising:
		if the location of the noun is visually adjacent to the location of the player:
			allow access;		
		otherwise:
			abide by the can't reach inside rooms rule;		
	otherwise:
		abide by the can't reach inside rooms rule;
		
section 2 - misc

Persuasion rule for asking people to try doing something: persuasion succeeds. 		

section 3 - model scenario

East Room is a room. "Beyond the metal grille, you see a small room." Erin is a person in the East Room. The earmuffs are in the East Room.

Main Room is a room. "The East wall of this room is a metal grille - you can see another room beyond. The West wall is a thick pane of glass, likewise exposing another room." Maya is a person in the Main Room. The mirror is in the Main Room.

West Room is a room. "Beyond the thick glass, you see a small room." Wendy is a person in the West Room. The whistle is in the West Room.

The player is in Main Room.

The East Room is visually adjacent to the Main Room.
The East Room is aurally adjacent to the Main Room.
The West Room is visually adjacent to the Main Room.

test look with "actions. x erin. x maya. x wendy."

test listen with "actions. listen to erin. listen to maya. listen to wendy."