Where can I find status line removing extension by Emily Short?

Authoring Inform 7
1

In my game the status line is not used. I’ve cleared it completely, however it leaves me with a rather ugly bar at the top of the screen. When googling I’ve seen posts mentioning Emily’s extension to do that, however now I cannot seem to find it.

2

I don’t think there’s a current version of that.

You can do it with Basic Screen Effects:

Include Basic Screen Effects by Emily Short.

Rule for constructing the status line:
	deepen status line to 0 rows;
	stop.

(EDIT: I had “do nothing” in there originally, but “stop” is clearer.)

The result is unpleasantly flickery in the IDE (at least the Mac IDE), but it looks fine in Gargoyle and Spatterlight. In Lectrote there’s a thin line remaining at the top of the screen, for CSS reasons.

4 Likes
3

It probably doesn’t matter, but I found this old post here about it.

→ https://intfiction.org/t/question-about-emily-shorts-status-line-removal-extension/1209/9

There’s a link to a now defunct dropbox file that I found on the wayback machine…

→ https://web.archive.org/web/20150109223109/https://dl.dropboxusercontent.com/u/947038/Status%20Line%20Removal.i7x

However the contents of the file are:

Version 4 of Status Line Removal by Emily Short begins here.

"Removes the status line entirely, for Z-machine or Glulx games where none is desired."

Use authorial modesty.


Section - Replacement of DrawStatusLine()

Include (-

Replace DrawStatusLine;


-) after "Definitions.i6t".

Include (-

[ DrawStatusLine;
]; 

-) after "Definitions.i6t".


Section - InitGlkWindow entry point (for use without Flexible Windows by Jon Ingold)

Include (-

#ifdef TARGET_GLULX;

  [ InitGlkWindow winrock;

     switch (winrock) {

! do not create a status window. 
     GG_STATUSWIN_ROCK: rtrue;

     }
     rfalse;  
  ];
#endif;

-) after "Definitions.i6t".


Section - Use Flexible Windows' InitGlkWindow routine (for use with Flexible Windows by Jon Ingold)

Use no status line.


Status Line Removal ends here.

---- Documentation ----

A very simple, single-purpose extension: include it if you wish to eliminate the status line from your game. (This may be useful when compiling a game to display on Zplet or another web-based interpreter where the status line looks bad with the web page's framing effects.)

Note that this extension may not be compatible with some Glulx windowing extensions.

Anyway, not to beat a dead horse, but… *kicks the horse*

Also, I have no idea how this sort of stuff works. Did I find the actual code file? I don’t know. Who cares. Whatever. :wink:

4

Looks fine in the Windows IDE, so might have something to do with how it is done on Mac?