Status bar displays nonsense in Gargoyle when play begins

My game starts with a boxed quotation followed by some introductory text before the game starts in earnest.

When play begins: 
	display the boxed quotation
	"SHIP TO: 
QUUDGE THE VOLUMINOUS
23 CRATER AVENUE, SUITE Z
SPOREVILLE, GREATER LOGPILE 86D13
PRINCIPALITY OF S'LURRP
XAQUION, CUDGEL SYSTEM
"; 
	show the current quotation;
	pause the game;
	say "[line break]CONTENT WARNING:  This work is intended for a mature adult audience.  It contains violence, alcohol and drug abuse, strong language, and suggestive themes.  Player discretion is advised.";
	wait for any key;
	say "[line break]Type HELP at any time.";
	wait for any key;
	clear the screen;
	say "[line break]Only one more package to deliver!";
	wait for any key;
	say "[line break]Your trusty yellow Parcel Express cargo craft is already deep within the Cudgel System, a planetary system inconveniently located on the far outskirts of the Ova.  Colloquially these outskirts are known as the Hinterlands (and typically avoided by tourists); but unlike most of the Hinterlands, the inhabited planets of the Cudgel System are members of the Consortium Of Known Occupied Worlds and - as such - are serviced by the Parcel Express Corporation.";
	wait for any key;
	say "[line break]You should be approaching the planet Xaquion in roughly two standard time units.  Fortunately there's a ParcEx landing pad a couple of blocks from the destination, at the intersection of Muck and Crater; so this should be a relatively quick delivery.  Then there's just the long ride back to the depot on Puscaat, and you can finally clock out for the weekend!";
	wait for any key;
	say "[line break]Hmm... the tank's almost empty.  Looks like you're going to have to touch down on the nearest outpost to refuel.";
	wait for any key;
	say "[line break]According to your Spacer's Atlas, there's a fueling station on the planet Fruppa IX.  Never heard of it.  Oh well...";
	wait for any key;
	clear the screen;
	say "[b]HINTERLANDS: DELIVERED![/b]";
	wait for any key;
	clear the screen.
Before starting the virtual machine: 
	now the left hand status line is ""; 
	now the right hand status line is "".

I also have a custom status line:



[STATUS LINE]
To say the player's capitalised surroundings:
	let the masthead be "[the player's surroundings]" in upper case;
	say the masthead.

Table of Fancy Status
left	central	right 
"Location: [the player's capitalised surroundings] ([map region of the location])"	""	"Score: [score]/[maximum score]"
"Near: [if a room is adjacent][list of adjacent rooms][end if][if a room is adjacent and a door is visible], [end if][if a door is visible][the list of visible doors][end if]"	""	""

Rule for constructing the status line:
	 fill status bar with Table of Fancy Status;
	 rule succeeds.

Rule for printing the name of an unvisited room (called the target) while constructing the status line: 
	let aim be the best route from the location to the target; 
	say "somewhere [aim]".
	
After printing the name of a visited room (called the target) while constructing the status line: 
	let aim be the best route from the location to the target;
	if aim is not nothing:
		say " ([aim])".
	
Rule for printing the name of a direction (called the aim) while constructing the status line: 
	choose row with a heading of the aim in the Table of Abbreviation; 
	say "[shortcut entry]".
	
Table of Abbreviation 
heading	shortcut
north	"N"
northeast	"NE"
northwest	"NW"
east	"E"
southeast	"SE"
south	"S"
southwest	"SW"
west	"W"
up	"U"
down	"D"
inside	"in"
outside	"out"
fore	"F"
aft	"A"
port	"P"
starboard	"S"

In most interpreters, the status line is completely blank until play actually begins (the first room).

However in Gargoyle, as soon as the game starts up (the boxed quotation), the status line shows the location as SOMEWHERE NOTHING with the region and exits of the game’s first room listed and a score of 0/16.

Is there a way to change my code such that Gargoyle displays the status line as blank until the game actually starts?

I’m not sure why Gargoyle is showing different behavior, but my solution would be:

Rule for constructing the status line:
	 if we have looked, fill status bar with Table of Fancy Status;
	 rule succeeds.
3 Likes