Examining multiple things, forcing run paragraph on.

This seems really simple, but I am just pulling my hair out over it. I want to be able to examine multiple things, and not introduce a paragraph break. For example:

Instead of examining yourself: try examining your body; try examining your face.

This spits out:

[code]>X me

Description of your body.

Description of your face.[/code]

I’d much prefer:


X me

Description of your body. Description of your face.

(or maybe
Description of your body.
Description of your face.)[/code]

Is there any way to prevent that paragraph break from being put in there? I’ve tried messing around with “run paragraph on”, but it doesn’t like that out of text.

P.S. I would just use

Instead of examining yourself: say "[description of your body] [description of your face]".

but frequently these things have many states, and I’ve used this sort of code:

Instead of examining your face: if A: say "blah"; if B: say "blah [if C]blah[end if] blah[if D] and blah[end if]."
So technically many of these things do not have descriptions assigned to them.

If there’s a way to use say "[description of your body] [description of your face]" , I am not picky and would love that too.


I’d love to know this too, but I’d probably do it this way:

[code]The description of yourself is “[face description]. [body description].”

The description of your face is “[face description].”

The description of your body is “[body description].”

To say face description…

To say body description…[/code]

This works in at least one case, but probably isn’t recommendable overall.

[code]A body is a kind of thing. A face is a kind of thing.
A body is a part of every person. A face is a part of every person.

Me-examining is a truth state that varies. Me-examining is usually false.
Every turn: Now me-examining is false.
The description of your body is “It’s a body.[if me-examining is true] [run paragraph on]”.
Instead of examining yourself:
now me-examining is true;
try examining your body;
say “[run paragraph on]”;
try examining your face;
now me-examining is false.

Carry out examining your body while me-examining is true:
say “[the description of your body]”;
stop the action.

The idea is that you want examining your body to work differently depending on whether you’re examining it directly or as part of your body, so you set the me-examining flag to see whether you’re examining your body, and that runs the paragraph on in the description. But the standard examining rule, which is a carry out examining rule, automatically prints a line break after the description, so you need to intercept that too with a special rule while me-examining; and you need to stop the action so they don’t both trigger. Which could mess up any “after examining” rules you have. If you don’t mind having two separate paragraphs with no line break, you could leave this bit out.

Anyway, this requires making sure that your face-description always ends with that conditional [run paragraph on], so another solution might be better. There are probably extensions out there that allow this.

Thanks so much, that worked really well!

Being woozy from sleeping pills, I decided to try doing it with rulebooks, and it sort of snowballed from there. Spoiler-spaced, since it is huge and rather pointless. :slight_smile:

"Ruling Body" by Björn Paulsen

A body part is a kind of thing. A body and a face are kinds of body part.
A body and a face are part of every man.

Appearance is an object-based rulebook.
An appearance rule for a face: say "It's a face.[run paragraph on]".
An appearance rule for a body: say "It's a body.[run paragraph on]".

The Court is a room. "This is the Imperial Court, where petitioners come from distant worlds to beg the favour of their sovereign. The atrium's endless expanse stretches out in every direction, broken only by towering columns, judiciously placed artwork, and equally silent if slightly less ornamental guards."

The throne is a supporter in the Court. Emperor Palpatine is a man on the throne. The description of Palpatine is "Palpatine grins skeletally as he beckons [one of]a[or]another[or]yet another[stopping] petitioner forward."

An appearance rule for Palpatine's face: say "Beneath the hood, the Emperor's face is a withered, half-melted ruin. His yellow eyes glitter in their dark sockets; his grin is terrible to behold.[run paragraph on]" instead.

An appearance rule for Palpatine's body: say "He's swathed in his customary robes[first time] (they appear simple, almost austere, but are probably fabulously expensive)[only], and from what you can tell, he's old and frail.[run paragraph on]" instead.

First carry out examining Palpatine:
	Consider the appearance rules for Palpatine's face;
	say " ";
	Consider the appearance rules for Palpatine's body;
	say "[paragraph break]".

Carry out examining a body part (called flesh):
	Consider the appearance rules for the flesh;
	say "[paragraph break]" instead.

Does the player mean examining the Emperor: it is likely.

For printing a locale paragraph about the throne:
	if the Emperor is on the throne, say "On his throne in the middle of the room sits the wizened Emperor Palpatine.";
	otherwise say "In the room's center is a dais with Emperor Palpatine's throne. For the moment, it is vacant.";
	set the locale priority of the throne to 0;
	continue the activity.

Every turn: Unless the current action is examining something, say "[SomethingSomethingDarkSide]".

To say SomethingSomethingDarkSide:
	if the number of filled rows in the Table of Cackling Villainy is 0:
		say "The Emperor [one of]smirks evilly.[or]cackles quietly to himself.[or]gives a brief snort; has he fallen asleep?[or]sneers.[at random]";
		choose a random row in the Table of Cackling Villainy;
		say "[taunt entry][line break]";
		blank out the whole row.

Table of Cackling Villainy
"'Surrounded by fools,' the Emperor sneers, as if to himself. His adjutant quickly complements him on his perspicacity."
"Palpatine leans forward in his chair, yellow eyes fixing on his adjutant. 'I think the time has come to embrace a more... proactive version of the constitution.'[paragraph break]'Capital idea, sire!'"
"A petitioner approaches, and timidly states his case for the creation of a pan-Imperial holiday. He's barely begun expounding on the significance of reindeer and mulled wine when the Emperor, growing bored, orders him thrown down a reactor shaft. They drag the fool away, his screams cut off by the closing of the double doors."
"A petitioner delivers a list of names protesting recent surveillance laws, which the Emperor politely accepts, promising to look into the matter."
"A prospective petitioner loses his nerve and beats a quiet retreat."